Mount Point Permissions

edit

Some tweaks to stivesso's answer:

1. You're doing a chown(1) to the user with the ID 755. You wanna do a chmod(1).
2. And /bin/mkdir -m 0755 /app (mkdir(1) has a “mode” parameter), unless your exec provider is 'shell' and you want to separate the chmod(1).
3. There's also a umask attribute.
4. defaults (as the mount option) should be clearly marked as a string.
5. You wanna use resource references to read resource attributes.

Eventually you'd end up with:

$_foo = '/app'

$_cmd = @("EOT"/L)
  /bin/mkdir -v -m 0755 ${Mount[$_foo]['name']} && \
  /bin/chown -v username:groupname ${Mount[$_foo]['name']}
  |-EOT

exec { $_foo:
  command  => $_cmd,
  creates  => Mount[$_foo]['name'],
  provider => 'shell',
  before   => Mount[$_foo],
}

mount { $_foo:
  ensure  => 'mounted',
  device  => "/dev/${lvattribute[vg]}/${lvattribute[name]}",
  fstype  => 'auto', # or whatever fstype it is
  options => 'defaults',
  dump    => 0, # 0 = do not dump
  pass    => 0, # 0 = do not do fsck
}

file { $_foo: 
  ensure  => 'directory', 
  mode    => '0644',
  require => Mount['/app'],
}

• Added -v verbose flag to mkdir/chown, because I want to have everything (not just the errmsg) in the logs, if something went wrong.
• Separated the command into a heredoc-variable, because I want long lines to be split up, and unfortunately heredocs don't work for resource definitions.

It is indeed a tricky situation, because you can change ownership of the filesystem directory system by using chown (exec) on the filesystem's mount point. But during the next puppet run it will change it again to 0755 and then chown will rewrite...

Anyway, my suggestion is to do it exactly as you'd be doing manually on System. Meaning, first, create the directory (using exec - mkdir) and give it the appropriate permission (unless it exists already). Then, mount the filesystem accordingly after the directory was created and finally set that directory permission. (See the metaparameters (before and require) added for exec and mount to control that ordering... Making sure that Filesystem permission is only applied after the mount)

Turning to Puppet, that will be something like:

    exec {'create_folder':
      command => 'mkdir /app && chmod 755 /app',
      unless      => 'test -d /app',
      path         => '/usr/bin:/usr/sbin:/bin',
      before      => Mount["/app"],
    }

    mount { "/app": 
      ensure   => 'mounted',
      device   => "/dev/${lvattribute[vg]}/${lvattribute[name]}",
      options => defaults,
      dump    => $dump,
      pass      => $pass,
      fstype   => $fs_type,
    }

  file { "/app": 
    ensure   => "directory", 
    mode     => "644", # or the one you want for the FS - YYY 
    require  => Mount[ "/app"],
  }