include a parameter conditionally

asked 2017-04-14 12:49:49 -0600

speramus
26 ●3

Here's a corosync define I have:

define cs_pacemaker::primitives::ip ($ip, $mask = 24, $monitor_interval = '10s', $stickiness = 0) {
  cs_primitive { $name:

    primitive_class => 'ocf',
    primitive_type  => 'IPaddr2',
    provided_by     => 'heartbeat',

    parameters      => {
      'ip'           => $ip,
      'cidr_netmask' => $mask
    },

    operations      => {
      'monitor' => {
      'interval' => $monitor_interval,
      }
    },

    metadata        => {
      'stickiness' => $stickiness
    },
  }
}

The problem is that I want to include the "metadata" block ONLY if $stickiness is over 0. What's the best way to do this?

answered 2017-04-16 23:26:04 -0600

natemccurdy
219 ●2 ●6

You can use an if statement to check the value of $stickiness, this this:

define cs_pacemaker::primitives::ip (
  $ip,
  $mask             = 24,
  $monitor_interval = '10s',
  $stickiness       = 0,
) {

  if $stickiness > 0 {
    $metadata = { stickiness => $stickiness }
  } else {
    $metadata = undef
  }

  cs_primitive { $name:
    primitive_class => 'ocf',
    primitive_type  => 'IPaddr2',
    provided_by     => 'heartbeat',
    parameters      => {
      'ip'           => $ip,
      'cidr_netmask' => $mask
    },
    operations      => {
      'monitor'  => {
        'interval' => $monitor_interval,
      }
    },
    metadata        => $metadata,
  }

}